* Econ512  Assignment 1
clear all
cd "C:\Users\qjhws\Desktop\Classes\512TA\hw1" // change the current directory
											 // please place all data and code in the same directory
											 
insheet using card.txt, clear	

* rename of all variables 
global varname " id nearc2 nearc4 educ age fatheduc motheduc weight momdad14"
global varname "$varname sinmom14 step14 reg661 reg662 reg663  reg664 reg665 reg666"
global varname "$varname reg667 reg668 reg669 south66 black smsa south smsa66"
global varname "$varname wage enroll married exper"
rename (v1-v29) ($varname)
								
gen ln_wage = ln(wage)		
						
* part a 
gen exper_2 = exper^2
reg ln_wage educ exper exper_2 south black 								
est store model_A  // store the estimate results


* part b 			
capture program drop mymle
program mymle
  version 13.1
  args lnf xb lnsigma
  quietly replace `lnf' = ln(normalden($ML_y1, `xb',exp(`lnsigma')))
end 


ml model lf mymle (xb: ln_wage = educ exper exper_2 south black) (lnsigma:)
ml maximize
est store model_B  // store the MLE result


* part c

ivregress 2sls ln_wage exper exper_2 south black (educ = nearc4)
est store model_C  

* part d
ivregress 2sls ln_wage exper exper_2 south black (educ = nearc4 nearc2 fatheduc motheduc)
est store model_D


* part e  // note, this gmm estimation assumes homoskedasticity. 
ivregress gmm ln_wage exper exper_2 south black (educ = nearc4)
est store model_e1


ivregress gmm ln_wage exper exper_2 south black (educ = nearc4 nearc2 fatheduc motheduc)
est store model_e2


* you need to install esttab
* type "findit esttab" in command window. 
* this command generate table in publication format
esttab model_* using result.csv, replace ///
compress nogap b(%6.3f) se pr2 ///
star(* 0.1  ** 0.05  *** 0.01)